home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 3 NO 6.st / XREF.ARC / XREF.LST < prev    next >
Encoding:
File List  |  1988-10-14  |  61.3 KB  |  1,684 lines
  1. ' ***************************************************************************
  2. '                    GFA Basic Cross Reference Utility
  3. '                          by David Archibald
  4. '                   Copyright 1988 Antic Publishing Inc.
  5. '
  6. ' ****************************************************************************
  7. '
  8. '
  9. Scr_alot%=15                         !amount of screen space allotted for the var/proc/label name.
  10. Max_width%=80-Scr_alot%-5            !maximum length of screen line for listing.
  11. Max_var%=500                         !max number of unique variables, procedure, and labels
  12. Max_proc%=200                        !the arrays can hold.
  13. Max_label%=150
  14. '
  15. Dim Var_list$(Max_var%,1)            !init the arrays that hold the var/proc/label
  16. Dim Proc_list$(Max_proc%,1)          !xref listings (line #'s and names).
  17. Dim Label_list$(Max_label%,1)
  18. Var_list$(1,0)="VARIABLES"
  19. Proc_list$(1,0)="PROCEDURES"
  20. Label_list$(1,0)="LABELS"
  21. Dim Var_tree%(Max_var%,2)
  22. Dim Proc_tree%(Max_proc%,2)
  23. Dim Label_tree%(Max_label%,2)
  24. '
  25. Free_var%=3                          !pointers to the next free space in the
  26. Free_proc%=3                         !arrays for insertion of a new unique var/proc/label.
  27. Free_label%=3                        !by starting at pos 3 "**** NONE ****" is written over if var/proc/label is found (see Proc. GET_FILE).
  28. '
  29. Proc_start%=0                        !where the procedure and label xref listings start
  30. Label_start%=0                       !in the line_ptr%() array (see Proc. LINE_CNT).
  31. '
  32. Total_lines%=0                       !total # of var/proc/label screen lines (used for window slider controls).
  33. Top_line%=0                          !line number of line being displayed at the top of the window.
  34. '
  35. Max_line_ptrs%=(Max_var%+Max_proc%+Max_label%)*3  !keeps track of where each line start/ends
  36. Dim Line_ptr%(Max_line_ptrs%,2)                   !in the xxx_list$(x,1) xref listing arrays (above).
  37. '
  38. Max_prg_lines%=3500                  !holds the program being xrefed.
  39. Dim The_prg$(Max_prg_lines%)
  40. Top_prg%=0                           !same as top_line% but for the program's window.
  41. Let Line_number%=0                   !same as total_lines% but for the program.
  42. '
  43. ' arrays used for the raster blit's
  44. '
  45. Dim Raster%(5),Blit_dnw1%(8),Blit_upw1%(8),Blit_dnw3%(8),Blit_upw3%(8)
  46. Dim Wrk_areaw1%(3),Wrk_areaw3%(3)
  47. Dim Width%(2),Height%(2),Planes%(2)
  48. Width%(0)=320
  49. Width%(1)=640             !pixel width of screen for low, med, and high rez.
  50. Width%(2)=640
  51. Height%(0)=200
  52. Height%(1)=200            !pixel height of screen for low, med, and high rez.
  53. Height%(2)=400
  54. Planes%(0)=4
  55. Planes%(1)=2              !number of planes for low, med, and high rez.
  56. Planes%(2)=1
  57. Rez%=0
  58. Let For_redraw1$=""       !the windows work areas are save in these strings
  59. Let For_redraw3$=""       !for later redraws.
  60. '
  61. Blk_startw1%=Max_prg_lines%+1      !variable for keeping track of where a block
  62. Blk_endw1%=-1                      !starts and ends.
  63. Blk_startw3%=Max_prg_lines%+1
  64. Blk_endw3%=-1
  65. '
  66. ' resource variables and define's
  67. '
  68. About_tree%=0             !resource address of "about xref..." dialog box.
  69. Srch_tree%=0              !resource address of the search for var/proc/label box.
  70. Show_tree%=0              !resource address of the show program line # box.
  71. Ld_tree%=0                !resource address of loading and xrefing box.
  72. Search_tree%=0            !resource address of searching box.
  73. Sort_tree%=0              !resource address of sorting box.
  74. Let Quit_tree%=0          !resource address quit printout, or save file, box.
  75. Aboutgfa%=0               !/* TREE */
  76. Aboutok%=6                !/* OBJECT in TREE #0 */
  77. Srchfor%=1                !/* TREE */
  78. Srchstr%=4                !/* OBJECT in TREE #1 */
  79. Srchok%=5                 !/* OBJECT in TREE #1 */
  80. Srchcanc%=6               !/* OBJECT in TREE #1 */
  81. Showline%=2               !/* TREE */
  82. Whatline%=3               !/* OBJECT in TREE #2 */
  83. Showok%=4                 !/* OBJECT in TREE #2 */
  84. Showcanc%=5               !/* OBJECT in TREE #2 */
  85. Let Loading%=3            !/* TREE */"
  86. Ldquit%=6                 !/* OBJECT in TREE #3 */
  87. Ldbox%=5                  !/* OBJECT in TREE #3 */
  88. Searcher%=4               !/* TREE */
  89. Lkstrbox%=4               !/* OBJECT in TREE #4 */
  90. Lkstr%=5                  !/* OBJECT in TREE #4 */
  91. Lknumbox%=8               !/* OBJECT in TREE #4 */
  92. Lknum%=9                  !/* OBJECT in TREE #4 */
  93. Lkquit%=10                !/* OBJECT in TREE #4 */
  94. Sorting%=5                !/* TREE */
  95. Let Quitprt%=6            !/* TREE */
  96. Cancprt%=1                !/* OBJECT in TREE #6 */
  97. Canptsv%=2                !/* OBJECT in TREE #6 */
  98. '            dialog routine equates.
  99. Obj_size%=24              !size of each object struct.
  100. Ob_state%=10              !state of of a button ect.
  101. Ob_spec%=12               !where ob_spec is in the OBJECT struct.
  102. Let Box_x%=0              !the coordinates of the dialog box.
  103. Let Box_y%=0
  104. Let Box_w%=0
  105. Let Box_h%=0
  106. Normal%=&H0
  107. Fmd_start%=&H0
  108. Fmd_grow%=&H1
  109. Fmd_shrink%=&H2
  110. Fmd_finish%=&H3
  111. '
  112. ' misc variables
  113. '
  114. Dim Xref_menu$(50)        !menu array.
  115. Dim Disable_item%(8)      !which menu items are disabled (used with control/key combinations).
  116. Dum%=0                    !catch-all variable.
  117. Indent%=0                 !for horz movement of the program window.
  118. File_out!=False           !if flag=TRUE than xref listing goes to the disk.
  119. Prt_flag!=False           !if flag=TRUE than xref listing goes to the printer.
  120. Aes_ret%=0                !the error # returned when calling a AES library function.
  121. Srch_string$=""           !for the FIND command's dialog box (holds the input string).
  122. Machine$=""               !holds the machine language program used by the get_whatever procedure.
  123. Path$=""                  !the default file path name.
  124. '
  125. ' xbios routines
  126. '
  127. Logbase%=3
  128. Let Getrez%=4
  129. '
  130. ' AES messages
  131. '
  132. Wm_redraw%=20
  133. Wm_topped%=21
  134. Wm_arrowed%=24
  135. Wm_hslid%=25
  136. Wm_vslid%=26
  137. Wf_workxywh%=4
  138. Wf_hslide%=8
  139. Wf_vslide%=9
  140. Wf_top%=10
  141. Wf_vhlsize%=15
  142. Wf_vslsize%=16
  143. '
  144. ' --------------------------  Init. of the program ------------------------
  145. '
  146. @Initiation
  147. '
  148. Path$=Chr$(Gemdos(&H19)+65)+":\"
  149. @Get_file                           !start the program by asking for the filename of the 1st prg to be xref'ed.
  150. On Menu  Gosub Menu
  151. On Menu Key Gosub Keys
  152. On Menu Message Gosub Messages
  153. On Menu Button 1,1,1 Gosub Left_button
  154. '
  155. ' ---------------------------- main loop -----------------------------------
  156. '
  157. Do
  158.   On Menu
  159. Loop
  160. '
  161. '
  162. ' ------------------ end of main loop (long, isn't it.) ---------------------
  163. '
  164. Procedure Initiation
  165.   '
  166.   Rez%=Xbios(Getrez%)
  167.   If Rez%=0
  168.     Alert 3,"I know that it's a|nuisance, but you must|be in medium rez to use|XREF.",1," EXIT ",T%
  169.     Edit
  170.   Endif
  171.   If Rez%=1                         !are we in medium rez?
  172.     T%=6                            !mediums standard font.
  173.     Cell_high%=8                    !font's cell height in pixels
  174.   Else
  175.     T%=13                           !high rez's standard font.
  176.     Cell_high%=16
  177.   Endif
  178.   Deftext 1,0,0,T%                  !set text font to defaults.
  179.   '
  180.   @Rsrc_load("XREF.RSC")        !load the resource file.
  181.   If Aes_ret%=0
  182.     Alert 3,"|Can't find the resource file|       XREF.RSC",1," QUIT ",Dum%
  183.     Edit
  184.   Endif
  185.   @Rsrc_gaddr(0,Aboutgfa%,*About_tree%)     !get the address's of the dialog boxes.
  186.   @Rsrc_gaddr(0,Srchfor%,*Srch_tree%)
  187.   @Rsrc_gaddr(0,Showline%,*Show_tree%)
  188.   @Rsrc_gaddr(0,Loading%,*Ld_tree%)
  189.   @Rsrc_gaddr(0,Searcher%,*Search_tree%)
  190.   @Rsrc_gaddr(0,Sorting%,*Sort_tree%)
  191.   @Rsrc_gaddr(0,Quitprt%,*Quit_tree%)
  192.   '
  193.   Raster%(0)=Xbios(Logbase%)        !used with BITBLT command.
  194.   Raster%(1)=Width%(Rez%)
  195.   Raster%(2)=Height%(Rez%)
  196.   Raster%(3)=Width%(Rez%)/16
  197.   Raster%(4)=0
  198.   Raster%(5)=Planes%(Rez%)
  199.   '
  200.   For T%=0 To 100                     !do the menu bar.
  201.     Read Xref_menu$(T%)
  202.     Exit If Xref_menu$(T%)="END"
  203.   Next T%
  204.   Xref_menu$(T%)=""
  205.   Xref_menu$(T%+1)=""
  206.   Menu Xref_menu$()
  207.   @Init_menu(2,False)                 !disable a bunch of menu items.
  208.   '
  209.   For T%=1 To 157                     !put get_whatever's machine language routine
  210.     Read Dum%                         !in the string.
  211.     Machine$=Machine$+Chr$(Dum%)
  212.   Next T%
  213.   '
  214. Return
  215. '
  216. ' -----------------------------------------------------------------------
  217. Procedure Menu
  218.   Local Selection$
  219.   '
  220.   Selection$=Xref_menu$(Menu(0))
  221.   '
  222.   If Selection$="  About Xref..."
  223.     Dpoke (About_tree%+((Aboutok%)*Obj_size%)+Ob_state%),Normal%    !de-select the OK button.
  224.     @Do_dial(About_tree%,*Dum%)
  225.   Else
  226.     If Selection$="  Open file...           ^O "
  227.       @Get_file
  228.     Else
  229.       If Selection$="  Save all of Xref...    ^V "
  230.         @Save_xref(0,Total_lines%-1)
  231.       Else
  232.         If Selection$="  Save block of Xref...  ^F "
  233.           @Save_xref(Blk_startw1%,Blk_endw1%)
  234.           Openw 1
  235.           @Unmark_blk
  236.         Else
  237.           If Selection$="  Quit                   ^Q "
  238.             @Quit
  239.           Else
  240.             If Selection$="  Search...       ^S "
  241.               @Find
  242.             Else
  243.               If Selection$="  Goto line #...  ^G "
  244.                 @Show_line_num
  245.               Else
  246.                 If Selection$="  All of Xref     ^P "
  247.                   @Print_xref(0,Total_lines%-1)
  248.                 Else
  249.                   If Selection$="  Block of Xref   ^B "
  250.                     @Print_xref(Blk_startw1%,Blk_endw1%)
  251.                     Openw 1
  252.                     @Unmark_blk
  253.                   Else
  254.                     If Selection$="  All of File     ^A "
  255.                       @Print_file(0,Line_number%-1)
  256.                     Else
  257.                       If Selection$="  Block of File   ^K "
  258.                         @Print_file(Blk_startw3%,Blk_endw3%)
  259.                         Openw 3
  260.                         @Unmark_blk
  261.                       Else
  262.                         If Selection$="  Unmark Block  ^U "
  263.                           @Unmark_blk
  264.                         Endif
  265.                       Endif
  266.                     Endif
  267.                   Endif
  268.                 Endif
  269.               Endif
  270.             Endif
  271.           Endif
  272.         Endif
  273.       Endif
  274.     Endif
  275.   Endif
  276.   '
  277.   Menu Off
  278. Return
  279. '
  280. ' -----------------------------------------------------------------------
  281. Procedure Keys
  282.   Local Key%,Which_wind%,Hand_w1%
  283.   '
  284.   Key%=Menu(14) And &HFF      !get keypress but get rid of upper 8 bits.
  285.   '
  286.   If Key%=&HF                   !control O for "  Open file...  ^O "
  287.     @Get_file
  288.   Else
  289.     If Key%=&H16 And Disable_item%(0)=True     !control V for "  Save all of Xref...    ^V "
  290.       @Save_xref(0,Total_lines%-1)
  291.     Else
  292.       If Key%=&H6 And Disable_item%(1)=True      !control F for "  Save block of Xref...  ^F "
  293.         @Save_xref(Blk_startw1%,Blk_endw1%)
  294.         Openw 1
  295.         @Unmark_blk
  296.       Else
  297.         If Key%=&H11                  !control X for "  Quit      ^Q "
  298.           @Quit
  299.         Else
  300.           If Key%=&H13 And Disable_item%(2)=True  !control S for "  Search... ^S "
  301.             @Find
  302.           Else
  303.             If Key%=&H7 And Disable_item%(3)=True  !control G for "Goto line #...^G "
  304.               @Show_line_num
  305.             Else
  306.               If Key%=&H10 And Disable_item%(4)=True  !control P for "All of Xref ^P "
  307.                 @Print_xref(0,Total_lines%-1)
  308.               Else
  309.                 If Key%=&H2 And Disable_item%(5)=True  !control B for "Block of Xref ^B"
  310.                   @Print_xref(Blk_startw1%,Blk_endw1%)
  311.                   Openw 1
  312.                   @Unmark_blk
  313.                 Else
  314.                   If Key%=&H1 And Disable_item%(6)=True  !control A for "All of File ^A"
  315.                     @Print_file(0,Line_number%-1)
  316.                   Else
  317.                     If Key%=&HB And Disable_item%(7)=True  !control K for "Block of File ^K"
  318.                       @Print_file(Blk_startw3%,Blk_endw3%)
  319.                       Openw 3
  320.                       @Unmark_blk
  321.                     Else
  322.                       If Key%=&H15 And Disable_item%(8)=True  !control U for "Unmark Block ^U"
  323.                         @Unmark_blk
  324.                       Endif
  325.                     Endif
  326.                   Endif
  327.                 Endif
  328.               Endif
  329.             Endif
  330.           Endif
  331.         Endif
  332.       Endif
  333.     Endif
  334.   Endif
  335.   '
  336. Return
  337. '
  338. ' -------------------------------------------------------------------------
  339. Procedure Messages
  340.   Local T%,Mesg%,Which_wind%,Hand_w1%
  341.   '
  342.   Mesg%=Menu(1)                   !get the message number.
  343.   Which_wind%=Menu(4)             !which window the message affects.
  344.   Hand_w1%=Dpeek(Windtab)         !the handle for window 1.
  345.   '
  346.   If Mesg%=Wm_redraw%
  347.     If Which_wind%=Hand_w1%
  348.       Put Wrk_areaw1%(0),Wrk_areaw1%(1),For_redraw1$,3
  349.     Else
  350.       Put Wrk_areaw3%(0),Wrk_areaw3%(1),For_redraw3$,3
  351.     Endif
  352.   Endif
  353.   If Mesg%=Wm_topped%
  354.     If Which_wind%=Hand_w1%
  355.       Openw 1
  356.     Else
  357.       Openw 3
  358.     Endif
  359.   Endif
  360.   If Mesg%=Wm_arrowed%
  361.     If Menu(5)=0                   !shaded area above the slider was clicked on.
  362.       If Which_wind%=Hand_w1%
  363.         @Previous_page(1,Top_line%,Total_lines%-1,*Top_line%)
  364.       Else
  365.         @Previous_page(3,Top_prg%,Line_number%-1,*Top_prg%)
  366.       Endif
  367.     Else
  368.       If Menu(5)=1                 !shaded area below the slider was clicked on.
  369.         If Which_wind%=Hand_w1%
  370.           @Next_page(1,Top_line%,Total_lines%-1,*Top_line%)
  371.         Else
  372.           @Next_page(3,Top_prg%,Line_number%-1,*Top_prg%)
  373.         Endif
  374.       Else
  375.         If Menu(5)=2               !up arrow was clicked.
  376.           If Which_wind%=Hand_w1%
  377.             @Previous_line(1,*Blit_dnw1%(),Top_line%,Total_lines%-1,*Top_line%)
  378.           Else
  379.             @Previous_line(3,*Blit_dnw3%(),Top_prg%,Line_number%-1,*Top_prg%)
  380.           Endif
  381.         Else
  382.           If Menu(5)=3             !down arrow was clicked.
  383.             If Which_wind%=Hand_w1%
  384.               @Next_line(1,*Blit_upw1%(),Top_line%,Total_lines%-1,*Top_line%)
  385.             Else
  386.               @Next_line(3,*Blit_upw3%(),Top_prg%,Line_number%-1,*Top_prg%)
  387.             Endif
  388.           Else
  389.             If Which_wind%<>Hand_w1%       !only window 3 has horz movement,
  390.               If Menu(5)=4                 !so don't bother to check these if the
  391.                 @Page_left                 !affected window is number one (the upper window).
  392.               Else
  393.                 If Menu(5)=5
  394.                   @Page_right
  395.                 Else
  396.                   If Menu(5)=6
  397.                     @Col_left
  398.                   Else
  399.                     If Menu(5)=7
  400.                       @Col_right
  401.                     Endif
  402.                   Endif
  403.                 Endif
  404.               Endif
  405.             Endif
  406.           Endif
  407.         Endif
  408.       Endif
  409.     Endif
  410.   Endif
  411.   If Mesg%=Wm_vslid%
  412.     If Which_wind%=Hand_w1%
  413.       @Vert_slider(Total_lines%,*Top_line%,1)
  414.     Else
  415.       @Vert_slider(Line_number%,*Top_prg%,3)
  416.     Endif
  417.   Endif
  418.   If Mesg%=Wm_hslid%            !only window 3 has horz slider.
  419.     Indent%=Menu(5)*185/1000    !convert slider amount in to "character units."
  420.     @Horz_slider
  421.   Endif
  422.   '
  423. Return
  424. '
  425. ' -------------------------------------------------------------------------
  426. Procedure Left_button
  427.   Local Y%,Active_wind%,Start_end%
  428.   '
  429.   Y%=Mousey                             !get the mouse's Y coordinates.
  430.   Disable_item%(8)=True                 !we now have a block marked, so enable unmark block command.
  431.   Menu 30,3
  432.   @Wind_get(0,Wf_top%,*Active_wind%,*Dum%,*Dum%,*Dum%)  !get which window is active.
  433.   If Active_wind%=Dpeek(Windtab)
  434.     Start_end%=Top_line%+(Y%/Cell_high%)  !figure out what line the mouse is pointing at.
  435.     If Start_end%<Blk_startw1%          !if it's less the the old starting block line #
  436.       Blk_startw1%=Start_end%           !then make it the new starting #.
  437.       Blk_endw1%=Start_end%             !end block equals it also so only one line is highlighted.
  438.     Else
  439.       Blk_endw1%=Start_end%             !if it's not < blk_startw1%, then it must be the end block line #.
  440.       Menu 24,3                         !enable print xref block & save xref block
  441.       Menu 13,3                         !menu selection.
  442.       Disable_item%(5)=True
  443.       Disable_item%(1)=True
  444.     Endif
  445.     @Full_scr(Top_line%,Total_lines%,1) !redraw the window and highlight the lines.
  446.   Else
  447.     Start_end%=Top_prg%+(Y%/Cell_high%) !same as above, but for the program window (the lower one).
  448.     If Start_end%<Blk_startw3%
  449.       Blk_startw3%=Start_end%
  450.       Blk_endw3%=Start_end%
  451.     Else
  452.       Blk_endw3%=Start_end%
  453.       Menu 27,3                         !enable print file block menu selection.
  454.       Disable_item%(7)=True
  455.     Endif
  456.     @Full_scr(Top_prg%,Line_number%,3)  !redraw lines and highlight the block.
  457.   Endif
  458.   '
  459. Return
  460. '
  461. ' -------------------------------------------------------------------------
  462. Procedure Unmark_blk
  463.   Local Active_wind%
  464.   '
  465.   @Wind_get(0,Wf_top%,*Active_wind%,*Dum%,*Dum%,*Dum%) !get which window is active.
  466.   If Active_wind%=Dpeek(Windtab)                       !reset the start/end block line #'s
  467.     Blk_startw1%=Max_line_ptrs%+1                      !to their default sizes.
  468.     Blk_endw1%=-1
  469.     Menu 24,2                           !disable print xref block & save xref block
  470.     Menu 13,2                           !menu selection.
  471.     Disable_item%(5)=False
  472.     Disable_item%(1)=False
  473.     @Full_scr(Top_line%,Total_lines%,1)
  474.   Else
  475.     Blk_startw3%=Max_prg_lines%+1
  476.     Blk_endw3%=-1
  477.     Menu 27,2                           !disable print file block menu selection.
  478.     Disable_item%(7)=False
  479.     @Full_scr(Top_prg%,Line_number%,3)
  480.   Endif
  481.   '
  482.   If Disable_item%(5)=False And Disable_item%(5)=False   !if neither the xref or program window have a marked block
  483.     Menu 30,2                                            !in them, then disable the unmark block command.
  484.     Disable_item%(8)=False
  485.   Endif
  486.   '
  487.   While Mousek<>0                       !don't return until the button is released. (if we don't wait,
  488.   Wend                                  !the screen is redraw over and over as long as the button is held down.)
  489. Return
  490. '
  491. ' -------------------------------------------------------------------------
  492. Procedure Quit
  493.   Local But%
  494.   '
  495.   Alert 2," Quit Xref?  ",1," YES |  NO  ",But%
  496.   If But%=1
  497.     Closew 1
  498.     Closew 3
  499.     Menu Kill
  500.     @Rsrc_free
  501.     Edit
  502.   Endif
  503. Return
  504. '
  505. ' -------------------------------------------------------------------------
  506. Procedure Get_file
  507.   Local But%,X_off%,Y_off%,Past%,How_much%,Last%,Now%,Per
  508.   '
  509.   But%=1
  510.   '
  511.   Repeat                                  !separate the path name from the file name and use it with FILESELECT.
  512.     Last%=Now%                            !this way we don't have to enter the default
  513.     Now%=Instr(Path$,"\",Last%+1)         !path name each time we select a file.
  514.   Until Now%=False
  515.   Path$=Left$(Path$,Last%)
  516.   Fileselect Path$+"*.LST","",Filename$
  517.   If Right$(Filename$,3)<>"LST" And Filename$<>""
  518.     Alert 1,"You can't fool me!|This file doesn't have a|LST extension.|Continue anyways?",1," YES |  NO  ",But%
  519.   Endif
  520.   If Filename$<>"" And But%=1
  521.     Path$=Filename$
  522.     '                                ---------  init the variables  ----------
  523.     For T%=2 To Free_var%-1
  524.       Var_list$(T%,1)=""                  !get rid of line #'s from last xref.
  525.       Var_list$(T%,0)=""
  526.       Var_tree%(T%,0)=0                   !clear the procedure insert_str's binary tree.
  527.       Var_tree%(T%,1)=0
  528.       Var_tree%(T%,2)=0
  529.     Next T%
  530.     For T%=2 To Free_proc%-1
  531.       Proc_list$(T%,1)=""
  532.       Proc_list$(T%,0)=""
  533.       Proc_tree%(T%,0)=0
  534.       Proc_tree%(T%,1)=0
  535.       Proc_tree%(T%,2)=0
  536.     Next T%
  537.     For T%=2 To Free_label%-1
  538.       Label_list$(T%,1)=""
  539.       Label_list$(T%,0)=""
  540.       Label_tree%(T%,0)=0
  541.       Label_tree%(T%,1)=0
  542.       Label_tree%(T%,2)=0
  543.     Next T%
  544.     For T%=0 To Line_number%-1            !get rid of the last program xrefed.
  545.       The_prg$(T%)=""
  546.     Next T%
  547.     Var_list$(3,0)="**** NONE ****"
  548.     Proc_list$(3,0)=Var_list$(3,0)
  549.     Label_list$(3,0)=Var_list$(3,0)
  550.     Free_var%=3
  551.     Free_proc%=3
  552.     Free_label%=3
  553.     Proc_start%=0
  554.     Label_start%=0
  555.     Let Line_number%=0
  556.     Top_prg%=0
  557.     Total_lines%=0
  558.     Top_line%=0
  559.     Indent%=0
  560.     Blk_startw1%=Max_line_ptrs%+1
  561.     Blk_endw1%=-1
  562.     Blk_startw3%=Max_prg_lines%+1
  563.     Blk_endw3%=-1
  564.     Aes_ret%=0
  565.     Srch_string$="@~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"+Chr$(0)        !room for 30 characters (used with the FIND dialog box).
  566.     '
  567.     @Draw_box(Ld_tree%)                                  !put the "Cross ref..." box on the screen.
  568.     @Objc_offset(Ld_tree%,Ldbox%,*X_off%,*Y_off%)        !get the screen location of the "percent of file done" bar.
  569.     @Clip(0)                   !disable clipping.
  570.     Deffill 1,2,1
  571.     Open "i",#1,Filename$
  572.     Per=Lof(#1)/200             !the file's size divided by 200 equals 1/2% on the "file completed" bar.
  573.     '
  574.     Do
  575.       Line Input #1,The_prg$(Line_number%)
  576.       @Parse_line
  577.       Inc Line_number%
  578.       How_much%=Loc(#1)/Per    !returns what percentage of the file has been loaded.
  579.       If How_much%>Past%       !if 1/2% or more of the file has been loaded, then update the bar.
  580.         Past%=How_much%
  581.         @V_bar(X_off%-1,Y_off%-1,X_off%+Past%,Y_off%+Cell_high%)  !add 1 pixel to the length of the bar for every 1/2% of the file completed.
  582.       Endif
  583.       Exit If Eof(#1)
  584.       If Mousek=1                                   !is the left mouse button pressed?
  585.         @Check_mouse_position(Ld_tree%,Ldquit%)
  586.       Endif
  587.       Exit If Aes_ret%=Ldquit% Or Inkey$=Chr$(13)   !exit if QUIT button selected or RETURN pressed.
  588.     Loop                                            !reading of file completed.
  589.     '
  590.     @Clip(1)             !re-enable clipping.
  591.     Close #1
  592.     @Erase_box
  593.     @Draw_box(Sort_tree%)
  594.     @Quick_sort(*Var_list$(),3,Free_var%-1)
  595.     @Quick_sort(*Proc_list$(),3,Free_proc%-1)
  596.     @Quick_sort(*Label_list$(),3,Free_label%-1)
  597.     @Erase_box
  598.     '
  599.     ' line count (used with window slider control).
  600.     '
  601.     @Line_cnt(*Var_list$(),Free_var%-1)
  602.     Proc_start%=Total_lines%                 !what cell the procedure's start in the line_ptr%() array.
  603.     @Line_cnt(*Proc_list$(),Free_proc%-1)
  604.     Label_start%=Total_lines%                !same as above, but where the labels start.
  605.     @Line_cnt(*Label_list$(),Free_label%-1)
  606.     '
  607.     @Open_wind
  608.     @Init_blit(Dpeek(Windtab),*Blit_dnw1%(),*Blit_upw1%(),*Wrk_areaw1%())
  609.     @Init_blit(Dpeek(Windtab+24),*Blit_dnw3%(),*Blit_upw3%(),*Wrk_areaw3%())
  610.     @Full_scr(0,Line_number%,3)
  611.     Openw 1                        !top window 1.
  612.     @Full_scr(0,Total_lines%,1)
  613.     @Init_menu(3,True)             !enable all menu items except for...
  614.     Menu 13,2                      ! save xref block menu selection.
  615.     Disable_item%(1)=False
  616.     Menu 24,2                      ! print xref block menu selection.
  617.     Disable_item%(5)=False
  618.     Menu 27,2                      ! print file block menu selection.
  619.     Disable_item%(7)=False
  620.     Menu 30,2                      ! unmark block menu selection.
  621.     Disable_item%(8)=False
  622.   Endif
  623.   '
  624. Return
  625. '
  626. ' -------------------------------------------------------------------------
  627. Procedure Parse_line
  628.   Local Flag!,Start%,T%,All_gosubs%,Temp$
  629.   Flag!=True
  630.   All_gosubs%=3
  631.   '
  632.   Poke Varptr(Machine$)+154,0        !reset the machine language routine's end-of-line flag.
  633.   Start%=1
  634.   While Mid$(The_prg$(Line_number%),Start%,1)=" "          !skip leading spaces.
  635.     Inc Start%
  636.   Wend
  637.   '
  638.   If Mid$(The_prg$(Line_number%),Start%,4)="GOTO"  !if the command GOTO is the 1st thing on the line
  639.     @Get_whatever(1,Start%+4,*Dum%,False)          !then get the label that follows it.
  640.   Else
  641.     If Mid$(The_prg$(Line_number%),Start%,7)="RESTORE"  !ditto for RESTORE.
  642.       @Get_whatever(1,Start%+7,*Dum%,False)
  643.     Else
  644.       If Mid$(The_prg$(Line_number%),Start%,3)<>"REM" And Mid$(The_prg$(Line_number%),Start%,1)<>"'" And Mid$(The_prg$(Line_number%),Start%,4)<>"DATA"
  645.         T%=Instr(The_prg$(Line_number%),"GOSUB")
  646.         If Mid$(The_prg$(Line_number%),Start%,2)="ON" And T%    !does the line have an ON...GOSUB command?
  647.           @Get_whatever(3,Start%+2,*Start%,False)               !get the variable that follows "ON".
  648.           Start%=T%
  649.           All_gosubs%=2             !if more than one label, don't treat them
  650.         Endif                       ! as variables.
  651.         If Mid$(The_prg$(Line_number%),Start%,9)="PROCEDURE"  !get the procedure's name.
  652.           @Get_whatever(2,Start%+9,*Start%,True)              !the TRUE flags this as the line of origin.
  653.         Else
  654.           If Mid$(The_prg$(Line_number%),Start%,5)="GOSUB"
  655.             @Get_whatever(2,Start%+5,*Start%,False)
  656.           Else
  657.             If Mid$(The_prg$(Line_number%),Start%,1)="@"
  658.               @Get_whatever(2,Start%,*Start%,False)
  659.             Endif
  660.           Endif
  661.         Endif
  662.         While Asc(Right$(Machine$,3))<>&HFF                   !look for variables. the end of the line when it =&FF
  663.           @Get_whatever(All_gosubs%,Start%,*Start%,False)
  664.         Wend
  665.       Endif
  666.     Endif
  667.   Endif
  668. Return
  669. '
  670. ' -------------------------------------------------------------------------
  671. ' which%=1 or 2. 1 if we're looking for a label, 2 for a procedure, and anything for variables.
  672. ' var_start%=what position in the string to start looking from.
  673. ' var_end%=is a pointer to pos% so the updated position can be returned.
  674. ' org_flag!=FALSE or TRUE. TRUE if the label or procedure name is on its line of origin.
  675. ' -------------------------------------------------------------------------
  676. '
  677. Procedure Get_whatever(Which%,Var_start%,Var_end%,Org_flag!)
  678.   Local Length%,Where%,Mach%,Temp$
  679.   '
  680.   Length%=Len(The_prg$(Line_number%))     !make sure we're not going to check an empty string.
  681.   If Length%>0
  682.     Mach%=Varptr(Machine$)
  683.     Call Mach%(Var_start%,Length%+1,The_prg$(Line_number%),Machine$)
  684.     Var_start%=Asc(Right$(Machine$,3))
  685.     Where%=Asc(Right$(Machine$,2))
  686.     If Var_start%<>&HFF
  687.       *Var_end%=Where%
  688.       If Right$(Machine$,1)="(" And Which%=3  !if the variable is an array, than
  689.         Inc Where%                            !we want the "(" following it to be
  690.       Endif                                   !part of the variable's name.
  691.       '
  692.       Temp$=Mid$(The_prg$(Line_number%),Var_start%,Where%-Var_start%)
  693.       '
  694.       If Which%=1                             !store the label following GOTO.
  695.         @Insert_str(Temp$,*Label_list$(),*Free_label%,Free_label%,False,*Label_tree%())
  696.       Else
  697.         If Right$(Machine$,1)=":" And Which%=3  !if it's a label don't put in var. list.
  698.           @Insert_str(Temp$,*Label_list$(),*Free_label%,Free_label%,True,*Label_tree%())
  699.         Else
  700.           If Which%=2                         !procedures and gosubs.
  701.             @Insert_str(Temp$,*Proc_list$(),*Free_proc%,Free_proc%,Org_flag!,*Proc_tree%())
  702.           Else
  703.             @Insert_str(Temp$,*Var_list$(),*Free_var%,Free_var%,False,*Var_tree%())  !variables.
  704.           Endif
  705.         Endif
  706.       Endif
  707.     Endif
  708.   Else
  709.     Poke Varptr(Machine$)+154,&HFF        !there isn't any line so quit and get another.
  710.   Endif
  711. Return
  712. '
  713. ' -------------------------------------------------------------------------
  714. ' string$=the variable/procedure/label that was extracted from the line.
  715. ' list%=is a array pointer. points to which array string$ will be added to.
  716. ' free%=is a pointer. used to update the free_xxxx% array pointer.
  717. ' last%=the next free cell in the list% array.
  718. ' org_flag!=the same as the get_whatever procedure.
  719. ' binary%=is a array pointer. it's a binary tree of pointers to the var/proc/label names.
  720. ' -------------------------------------------------------------------------
  721. '
  722. Procedure Insert_str(String$,List%,Free%,Last%,Org_flag!,Binary%)
  723.   Local T%
  724.   '
  725.   Swap *List%,Temp$()
  726.   Swap *Binary%,Tree%()
  727.   T%=2
  728.   While Temp$(Tree%(T%,1),0)<>String$       !search the binary tree for a match to the var/proc/label.
  729.     If String$<Temp$(Tree%(T%,1),0)         !if a node = 0 than the end of the tree was reached
  730.       If Tree%(T%,0)=0                      !with no match found. add the new var/proc/label to the tree's list.
  731.         Tree%(T%,0)=Last%
  732.         Tree%(Last%,1)=Last%
  733.         Temp$(Last%,0)=String$
  734.         Inc Last%
  735.       Endif
  736.       T%=Tree%(T%,0)         !get left node.
  737.     Else
  738.       If Tree%(T%,2)=0
  739.         Tree%(T%,2)=Last%
  740.         Tree%(Last%,1)=Last%
  741.         Temp$(Last%,0)=String$
  742.         Inc Last%
  743.       Endif
  744.       T%=Tree%(T%,2)         !get right node.
  745.     Endif
  746.   Wend
  747.   *Free%=Last%
  748.   '
  749.   @Insert_line_num(*Temp$(),T%,Org_flag!)  !add the gfa prg's line number to the var/proc/label's list.
  750.   Swap *Binary%,Tree%()
  751.   Swap *List%,Temp$()
  752. Return
  753. '
  754. ' -------------------------------------------------------------------------
  755. '          adds a lines line number to a var/proc/labels xref list.
  756. ' -------------------------------------------------------------------------
  757. ' each var/proc/labels referenced line numbers are concatenated in one string.
  758. ' When adding another line number to the string will exceed the screens width
  759. ' (max_width%) and cause a wrap-around on printout, the "end of the line"
  760. ' is marked with a zero (chr$(0)) and a "new" line is started.
  761. ' (Confused? see the Procedure line_cnt, to see how these lines are broke up.)
  762. ' -------------------------------------------------------------------------
  763. ' list%=the same as the insert_str procedure.
  764. ' which_line%=which cell in the list% array the var/proc/label is stored.
  765. ' org_flag!=still the same as the get_whatever procedure.
  766. ' -------------------------------------------------------------------------
  767. '
  768. Procedure Insert_line_num(List%,Which_line%,Org_flag!)
  769.   Local L_start%,L_end%,Blank$,Num$
  770.   '
  771.   Num$=Str$(Line_number%+1)
  772.   Marker$=Chr$(0)             !marks the end of a line (all of the line numbers are together in one string).
  773.   Swap *List%,Temp$()
  774.   '
  775.   Repeat                          !find the start of the last line in the string.
  776.     L_start%=L_end%+1
  777.     L_end%=Instr(Temp$(Which_line%,1),Marker$,L_start%)
  778.   Until L_end%=False
  779.   If Len(Mid$(Temp$(Which_line%,1),L_start%))+Len(Num$)<Max_width%  !if adding another line number won't cause a wrap-around,
  780.     Marker$=""                                                      !then clear the end-of-line marker.
  781.   Endif
  782.   '
  783.   If Org_flag!
  784.     Blank$=" *"                  !flag line number as line of origin.
  785.   Else
  786.     Blank$=" "
  787.   Endif
  788.   '
  789.   If Instr(Temp$(Which_line%,1),Blank$+Num$)=False                  !check if this line number is already in the var/proc/labels xref list.
  790.     Temp$(Which_line%,1)=Temp$(Which_line%,1)+Marker$+Blank$+Num$   !if not add the line number to it's list of line numbers.
  791.   Endif
  792.   '
  793.   Swap *List%,Temp$()
  794. Return
  795. '
  796. ' -------------------------------------------------------------------------
  797. Procedure Quick_sort(Array%,Left%,Right%)
  798.   Local I%,J%,Key$
  799.   '
  800.   Swap *Array%,Temp$()
  801.   '
  802.   I%=Left%
  803.   J%=Right%
  804.   Key$=Temp$((Left%+Right%)/2,0)
  805.   '
  806.   Repeat
  807.     While Temp$(I%,0)<Key$ And I%<Right%
  808.       Inc I%
  809.     Wend
  810.     While Key$<Temp$(J%,0) And J%>Left%
  811.       Dec J%
  812.     Wend
  813.     If I%<=J%
  814.       Swap Temp$(I%,0),Temp$(J%,0)
  815.       Swap Temp$(I%,1),Temp$(J%,1)
  816.       Inc I%
  817.       Dec J%
  818.     Endif
  819.   Until I%>J%
  820.   '
  821.   Swap *Array%,Temp$()
  822.   '
  823.   If Left%<J%
  824.     @Quick_sort(Array%,Left%,J%)
  825.   Endif
  826.   If I%<Right%
  827.     @Quick_sort(Array%,I%,Right%)
  828.   Endif
  829. Return
  830. '
  831. ' -------------------------------------------------------------------------
  832. ' we need to know the total number of lines so we can size and position the
  833. ' slider, so count the number of end of line markers (zero) in the
  834. ' var_list$(), proc_list$(), and label_list$() arrays.
  835. ' also, since each var/proc/labels lines are combined in one string we need to
  836. ' know where each of those lines starts, and ends, in each string.
  837. ' -------------------------------------------------------------------------
  838. '
  839. Procedure Line_cnt(Array%,Entrys%)
  840.   Local T%,T1%,Zero%,Marker$
  841.   '
  842.   Marker$=Chr$(0)
  843.   Swap *Array%,Temp$()
  844.   '
  845.   If Entrys%=2                            !if the array is empty, make sure
  846.     Inc Entrys%                           !we get the '**** NONE ****' mesg.
  847.   Endif
  848.   For T%=0 To Entrys%
  849.     If Len(Temp$(T%,0))>Scr_alot%         !inc line count by 1 if variables
  850.       Let Line_ptr%(Total_lines%,0)=T%    !name is > than the screen space
  851.       Inc Total_lines%                    !allotted for it. (it prints on a
  852.       Zero%=1                             !line all by its self. no numbers.)
  853.     Endif             !use zero% as a flag: =0 prt var. >=1 don't prt var.
  854.     T1%=1
  855.     Do
  856.       Let Line_ptr%(Total_lines%,0)=T%       !which cell the var/proc/labels name is in.
  857.       Let Line_ptr%(Total_lines%,1)=Zero%    !what position in the string the line starts.
  858.       Zero%=Instr(Temp$(T%,1),Marker$,Zero%) !find the end of the line.
  859.       Let Line_ptr%(Total_lines%,2)=Zero%-Line_ptr%(Total_lines%,1)  !what position the line ends at.
  860.       Exit If Zero%=False                    !no more lines in this string!
  861.       Inc Zero%
  862.       Inc Total_lines%
  863.       Inc T1%
  864.     Loop
  865.     Let Line_ptr%(Total_lines%,2)=30000      !use a LARGE number as the ending position of the last line.
  866.     Inc Total_lines%
  867.   Next T%
  868.   '
  869.   Swap *Array%,Temp$()
  870. Return
  871. '
  872. ' -------------------------------------------------------------------------
  873. Procedure Find
  874.   Local But%,T%,Top%,Length%,S%,Found%,Group$
  875.   '
  876.   '
  877.   Dpoke (Srch_tree%+(Srchok%*Obj_size%)+Ob_state%),Normal%      !de-select the OK button.
  878.   Dpoke (Srch_tree%+(Srchcanc%*Obj_size%)+Ob_state%),Normal%    !de-select the CANCEL button.
  879.   Lpoke (Lpeek(Srch_tree%+(Srchstr%*Obj_size%)+Ob_spec%)),Varptr(Srch_string$)   !point the dialog boxes' TEDINFO to our string.
  880.   @Do_dial(Srch_tree%,*But%)
  881.   '
  882.   Length%=Instr(Srch_string$,Chr$(0))-1
  883.   If But%=Srchok% And Length%>0 And Left$(Srch_string$,1)<>"@"
  884.     @Draw_box(Search_tree%)
  885.     '
  886.     Top%=Top_line%                 !save the present top line.
  887.     Inc Top_line%                  !start comparing one line after the top line.
  888.     If Top_line%<Proc_start%       !is the top line in the variable list?
  889.       Group$="variables"  !if yes then start search there.
  890.       @Search(Proc_start%-1,*Var_list$(),*Found%,Length%,Group$)
  891.     Endif
  892.     If Top_line%>=Proc_start% And Top_line%<Label_start% And Found%=False  !if top line is in the procedure list or
  893.       Group$="procedures"                                          !the variables were searched without a match then...
  894.       @Search(Label_start%-1,*Proc_list$(),*Found%,Length%,Group$)
  895.     Endif
  896.     If Top_line%>=Label_start% And Found%=False
  897.       Group$="  labels"
  898.       @Search(Total_lines%,*Label_list$(),*Found%,Length%,Group$)
  899.     Endif
  900.     '
  901.     S%=Max(0,(28-Length%)/2)       !center srch_string$ in the alert box (or close to it).
  902.     If Found%=True
  903.       Alert 0,Space$(S%)+Left$(Srch_string$,Length%)+"|"+String$(29,"-")+"|      was found in the       |"+Space$(9)+Group$,1,"  OK  ",But%
  904.       If Top_line%>Total_lines%-8         !if less than 9 lines follow top_line% then
  905.         Sub Top_line%,8                   !adjust it so a full window is written.
  906.       Endif
  907.       Openw 1                             !top the window.
  908.       @Full_scr(Top_line%,Total_lines%,1) !display the line at the top of the window.
  909.     Else
  910.       Alert 1,Space$(S%)+Left$(Srch_string$,Length%)+"|"+String$(29,"-")+"|      was not found."+Space$(10),1,"  OK  ",But%
  911.       Top_line%=Top%       !restore top_line%'s original value.
  912.     Endif
  913.   Endif
  914.   @Erase_box
  915. Return
  916. '
  917. ' -------------------------------------------------------------------------
  918. Procedure Search(End%,Array%,Flag%,L%,Grp$)
  919.   Local Mx%,My%,Mb%,T%,Cnt%,String$,Num$
  920.   '
  921.   Swap *Array%,Temp$()
  922.   String$=Left$(Srch_string$,L%)          !get just the input string and ignore the left over "~~~~"'s.
  923.   Cnt%=End%-Top_line%+1
  924.   Grp$=Grp$+Chr$(0)
  925.   '
  926.   Lpoke Search_tree%+(Lkstr%*Obj_size%)+Ob_spec%,Varptr(Grp$)     !point the dialog boxes' ob_spec to the string.
  927.   @Objc_draw(Search_tree%,Lkstrbox%,2,Box_x%,Box_y%,Box_w%,Box_h%)
  928.   '
  929.   '
  930.   For T%=Top_line% To End%                               !truncate and compare the same amount of character in the
  931.     Exit If Left$(Temp$(Line_ptr%(T%,0),0),L%)=String$ And Line_ptr%(T%,1)=0  !var/proc/label list to same length that the string$ has.
  932.     Dec Cnt%
  933.     Num$=Str$(Cnt%)+Chr$(0)
  934.     Lpoke Search_tree%+(Lknum%*Obj_size%)+Ob_spec%,Varptr(Num$)     !point the dialog boxes' ob_spec to the string.
  935.     @Objc_draw(Search_tree%,Lknumbox%,2,Box_x%,Box_y%,Box_w%,Box_h%)
  936.     If Mousek=1                                          !is the left mouse button pressed?
  937.       @Graf_mkstate(*Mx%,*My%,*Dum%,*Dum%)
  938.       @Objc_find(Search_tree%,Lkquit%,10,Mx%,My%)        !is the mouse over the QUIT button.
  939.       If Aes_ret%=Lkquit%
  940.         T%=End%
  941.         *Flag%=2
  942.       Endif
  943.     Endif
  944.   Next T%
  945.   Top_line%=T%
  946.   If Top_line%<=End%          !hurray! we found a match.
  947.     *Flag%=True
  948.   Endif
  949.   '
  950.   Swap *Array%,Temp$()
  951. Return
  952. '
  953. ' -------------------------------------------------------------------------
  954. Procedure Show_line_num
  955.   Local But%,Num%,Temp$
  956.   '
  957.   Temp$="@____"+Chr$(0)
  958.   '
  959.   Dpoke (Show_tree%+(Showok%*Obj_size%)+Ob_state%),Normal%      !de-select the OK button.
  960.   Dpoke (Show_tree%+(Showcanc%*Obj_size%)+Ob_state%),Normal%    !de-select the CANCEL button.
  961.   Lpoke (Lpeek(Show_tree%+(Whatline%*Obj_size%)+Ob_spec%)),Varptr(Temp$)   !point the dialog boxes' TEDINFO to the string.
  962.   @Do_dial(Show_tree%,*But%)
  963.   If But%=Showok%
  964.     Num%=Val(Temp$)-1
  965.     If Num%>=0 And Num%<=Line_number%     !if it's <0 or > then the number of lines in the prg,
  966.       Top_prg%=Num%                       !don't do anything, otherwise top_prg%=the entered number
  967.       If Top_prg%>Line_number%-8          !if less than 9 lines follow top_prg% then
  968.         Sub Top_prg%,8                    !adjust it so a full window is written.
  969.       Endif
  970.       Openw 3                             !top the window.
  971.       @Full_scr(Top_prg%,Line_number%,3)  !put the inputed line at the top of the window.
  972.     Endif
  973.   Endif
  974. Return
  975. '
  976. '
  977. ' **********************  screen output routines  ***********************
  978. '
  979. '
  980. '
  981. ' -------------------------------------------------------------------------
  982. ' wind%=which window we're operating on.
  983. ' blit%=a pointer to an array. the array=the screen coordinates to move the screen up 1 line.
  984. ' top%=number of the line at the top of the window.
  985. ' total%=the total number of lines.
  986. ' a%=a pointer. used to update the line-at-the-top-of-the-window variable.
  987. ' -------------------------------------------------------------------------
  988. '
  989. Procedure Next_line(Wind%,Blit%,Top%,Total%,A%)
  990.   '
  991.   Swap *Blit%,Temp%()
  992.   '
  993.   If Top%+9<=Total%                         !are there any lines left?
  994.     Inc Top%
  995.     @Wind_set(Menu(4),Wf_vslide%,Int(1000*Top%/(Total%-8))) !move the vert slider to its new position.
  996.     Text 8,Cell_high%,Space$(77)            !clear the top line.
  997.     Bitblt Raster%(),Raster%(),Temp%()      !move the screen up one line.
  998.     Text 8,9*Cell_high%,Space$(77)          !clear the bottom line.
  999.     @Print_line(Top%+8,9*Cell_high%,Wind%)
  1000.     *A%=Top%            !update global top line pointer.
  1001.     @Save_scr(Wind%)
  1002.   Endif
  1003.   '
  1004.   Swap *Blit%,Temp%()
  1005. Return
  1006. '
  1007. ' -------------------------------------------------------------------------
  1008. ' blit%=a pointer to an array. same as next_line, but moves the screen down 1 line.
  1009. ' all others the same as the next_line procedure.
  1010. ' -------------------------------------------------------------------------
  1011. '
  1012. Procedure Previous_line(Wind%,Blit%,Top%,Total%,A%)
  1013.   '
  1014.   Swap *Blit%,Temp%()
  1015.   '
  1016.   If Top%<>0
  1017.     Dec Top%
  1018.     @Wind_set(Menu(4),Wf_vslide%,Int(1000*Top%/(Total%-8))) !move the vert slider to its new position.
  1019.     Text 8,9*Cell_high%,Space$(77)            !clear the bottom line.
  1020.     Bitblt Raster%(),Raster%(),Temp%()        !move the screen down one line.
  1021.     Text 8,Cell_high%,Space$(77)              !clear the top line.
  1022.     @Print_line(Top%,Cell_high%,Wind%)
  1023.     *A%=Top%           !update global top line pointer.
  1024.     @Save_scr(Wind%)
  1025.   Endif
  1026.   '
  1027.   Swap *Blit%,Temp%()
  1028. Return
  1029. '
  1030. ' -------------------------------------------------------------------------
  1031. Procedure Next_page(Wind%,Top%,Total%,A%)
  1032.   Local T%
  1033.   '
  1034.   If Top%+17<=Total%
  1035.     Add Top%,9
  1036.   Else
  1037.     Top%=Total%-8
  1038.   Endif
  1039.   *A%=Top%
  1040.   '
  1041.   @Full_scr(Top%,Total%,Wind%)
  1042. Return
  1043. '
  1044. ' -------------------------------------------------------------------------
  1045. Procedure Previous_page(Wind%,Top%,Total%,A%)
  1046.   Local T%
  1047.   '
  1048.   Top%=Max(Top%-9,0)
  1049.   *A%=Top%
  1050.   '
  1051.   @Full_scr(Top%,Total%,Wind%)
  1052. Return
  1053. '
  1054. ' -------------------------------------------------------------------------
  1055. Procedure Page_left
  1056.   '
  1057.   Indent%=Max(Indent%-70,0)
  1058.   @Horz_slider
  1059. Return
  1060. '
  1061. ' -------------------------------------------------------------------------
  1062. Procedure Page_right
  1063.   '
  1064.   Indent%=Min(Indent%+70,185)
  1065.   @Horz_slider
  1066. Return
  1067. '
  1068. ' -------------------------------------------------------------------------
  1069. Procedure Col_left
  1070.   '
  1071.   Indent%=Max(Indent%-1,0)
  1072.   @Horz_slider
  1073. Return
  1074. '
  1075. ' -------------------------------------------------------------------------
  1076. Procedure Col_right
  1077.   '
  1078.   Indent%=Min(Indent%+1,185)
  1079.   @Horz_slider
  1080. Return
  1081. '
  1082. ' -------------------------------------------------------------------------
  1083. Procedure Vert_slider(Total%,A%,Wind%)
  1084.   Local Top%
  1085.   '
  1086.   Top%=Menu(5)*(Total%-9)/1000     !convert slider amount in to "document units" (lines).
  1087.   *A%=Top%
  1088.   @Full_scr(Top%,Total%,Wind%)
  1089. Return
  1090. '
  1091. ' -------------------------------------------------------------------------
  1092. Procedure Horz_slider
  1093.   '
  1094.   @Wind_set(Menu(4),Wf_hslide%,Int(1000*Indent%/185))     !move the horz slider to its new position.
  1095.   @Full_scr(Top_prg%,Line_number%,3)
  1096. Return
  1097. '
  1098. ' -------------------------------------------------------------------------
  1099. Procedure Full_scr(Top%,Total%,Wind%)
  1100.   Local T%,Prt_at%
  1101.   '
  1102.   If Wind%=1                                      !clear the window.
  1103.     Deffill 0,1
  1104.     @V_bar(Wrk_areaw1%(0),Wrk_areaw1%(1),Wrk_areaw1%(2),Wrk_areaw1%(3))
  1105.     Deffill 1,2,1
  1106.   Else
  1107.     Deffill 0,1
  1108.     @V_bar(Wrk_areaw3%(0),Wrk_areaw3%(1),Wrk_areaw3%(2),Wrk_areaw3%(3))
  1109.     Deffill 1,2,1
  1110.   Endif
  1111.   @Wind_set(Dpeek(Windtab+((Wind%-1)*12)),Wf_vslide%,Int(1000*Top%/(Total%-9))) !move the vert slider to its new position.
  1112.   For T%=Top% To Top%+8
  1113.     Add Prt_at%,Cell_high%
  1114.     @Print_line(T%,Prt_at%,Wind%)
  1115.   Next T%
  1116.   @Save_scr(Wind%)
  1117. Return
  1118. '
  1119. ' -------------------------------------------------------------------------
  1120. Procedure Save_scr(Wind%)
  1121.   '                   !save the new screen incase a redraw message is received.
  1122.   If Wind%=1
  1123.     Get Wrk_areaw1%(0),Wrk_areaw1%(1),Wrk_areaw1%(2),Wrk_areaw1%(3),For_redraw1$
  1124.   Else
  1125.     Get Wrk_areaw3%(0),Wrk_areaw3%(1),Wrk_areaw3%(2),Wrk_areaw3%(3),For_redraw3$
  1126.   Endif
  1127.   '
  1128. Return
  1129. '
  1130. '
  1131. ' -------------------------------------------------------------------------
  1132. ' which_line%=which cell of line_ptr%() array the number of the line to be printed is in.
  1133. ' pos%=on what screen line to print the line.
  1134. ' wind%=which window we're sending the line too.
  1135. ' -------------------------------------------------------------------------
  1136. '
  1137. Procedure Print_line(Which_line%,Pos%,Wind%)
  1138.   Local Num$
  1139.   '
  1140.   If Wind%=1
  1141.     If Which_line%<Proc_start%                !which array is the line in?
  1142.       @Output(*Var_list$(),Pos%,Which_line%)
  1143.     Else
  1144.       If Which_line%>=Proc_start% And Which_line%<Label_start%
  1145.         @Output(*Proc_list$(),Pos%,Which_line%)
  1146.       Else
  1147.         @Output(*Label_list$(),Pos%,Which_line%)
  1148.       Endif
  1149.     Endif
  1150.     '
  1151.   Else                                                          !print a program line.
  1152.     Num$=Str$(Which_line%+1)
  1153.     Text 8,Pos%,Num$+"  "+Mid$(The_prg$(Which_line%),Indent%+1)
  1154.     If Which_line%>=Blk_startw3% And Which_line%<=Blk_endw3%    !do we highlight a block of text?
  1155.       Graphmode 2
  1156.       @Vr_recfl(Wrk_areaw3%(0)+8,(Pos%-Cell_high%)+Wrk_areaw3%(1)+3,Min(Max(8*(Len(The_prg$(Which_line%))+Len(Num$)+4-Indent%),16),8*77),Pos%+Wrk_areaw3%(1)+2)
  1157.       Graphmode 1
  1158.     Endif
  1159.   Endif
  1160.   '
  1161. Return
  1162. '
  1163. ' -------------------------------------------------------------------------
  1164. ' array%=an array pointer. points to the array where the line to be printed is.
  1165. ' prt_at%=which screen line to print the line on.
  1166. ' which_line%=which line to print.
  1167. ' -------------------------------------------------------------------------
  1168. '
  1169. Procedure Output(Array%,Prt_at%,Which_line%)
  1170.   Local Length%
  1171.   '
  1172.   Swap *Array%,Temp$()
  1173.   '
  1174.   If Line_ptr%(Which_line%,1)=0                       !only prt the var/label/proc
  1175.     If Prt_flag!=False
  1176.       Text 8,Prt_at%,Temp$(Line_ptr%(Which_line%,0),0)  !on the 1st line (if there is
  1177.     Else                                                !more than one.)
  1178.       Print #5,Temp$(Line_ptr%(Which_line%,0),0);       !output to printer instead of screen.
  1179.     Endif
  1180.     Length%=Len(Temp$(Line_ptr%(Which_line%,0),0))
  1181.     If Length%>Scr_alot%                        !indent 1st line scr_alot% amt
  1182.       Length%=0                                 !of spaces minus the length of
  1183.     Endif                                       !the var/label/proc.
  1184.   Endif
  1185.   '
  1186.   If Prt_flag!=False
  1187.     Text (Scr_alot%+1)*8,Prt_at%,Mid$(Temp$(Line_ptr%(Which_line%,0),1),Line_ptr%(Which_line%,1),Line_ptr%(Which_line%,2))
  1188.     '
  1189.     If Which_line%>=Blk_startw1% And Which_line%<=Blk_endw1%  !highlight a block of text.
  1190.       Graphmode 2
  1191.       @Vr_recfl(Wrk_areaw1%(0)+8,(Prt_at%-Cell_high%)+Wrk_areaw1%(1)+3,Min(8*(Len(Mid$(Temp$(Line_ptr%(Which_line%,0),1),Line_ptr%(Which_line%,1),Line_ptr%(Which_line%,2)))+Scr_alot%+1),8*77),Prt_at%+Wrk_areaw1%(1)+2)
  1192.       Graphmode 1
  1193.     Endif
  1194.     '
  1195.   Else
  1196.     Print #5,Space$(Scr_alot%-Length%);Mid$(Temp$(Line_ptr%(Which_line%,0),1),Line_ptr%(Which_line%,1),Line_ptr%(Which_line%,2))
  1197.   Endif
  1198.   '
  1199.   Swap *Array%,Temp$()
  1200. Return
  1201. '
  1202. '
  1203. ' *********************  printer (and file) output routines  **************
  1204. '
  1205. '
  1206. Procedure Save_xref(Save_start%,Save_end%)
  1207.   Local Ext%,Last%,Now%,Save_filename$
  1208.   '
  1209.   File_out!=True
  1210.   Repeat                                  !separate the path name from the file name and use it with FILESELECT.
  1211.     Last%=Now%
  1212.     Now%=Instr(Path$,"\",Last%+1)
  1213.   Until Now%=False
  1214.   '
  1215.   Ext%=Instr(Path$,".",Last%+1)           !find where the extension starts.
  1216.   If Ext%=0                               ! if there isn't a extension...
  1217.     Ext%=9
  1218.   Else
  1219.     Ext%=Ext%-Last%
  1220.   Endif
  1221.   Save_filename$=Mid$(Path$,Last%+1,Ext%-1)+".xfr"    !default output name equals input name but with .xfr extension.
  1222.   If Len(Save_filename$)=4
  1223.     Save_filename$="default.xfr"                      !if there isn't a file name, than really make it default.
  1224.   Endif
  1225.   '
  1226.   Fileselect Left$(Path$,Last%)+"*.xfr",Save_filename$,Save_filename$
  1227.   If Save_filename$<>""
  1228.     Open "o",#5,Save_filename$
  1229.     @Print_xref(Save_start%,Save_end%)
  1230.   Endif
  1231.   '
  1232.   File_out!=False
  1233. Return
  1234. '
  1235. ' -------------------------------------------------------------------------
  1236. Procedure Print_xref(Start%,End%)
  1237.   Local But%,T%,Sp%,Temp$
  1238.   '
  1239.   If File_out!=True        !file_out!=TRUE if sending output to disk file.
  1240.     Temp$="Writing file..."+Chr$(0)
  1241.     Lpoke (Quit_tree%+(Canptsv%*Obj_size%)+Ob_spec%),Varptr(Temp$)   !point the dialog boxes' ob_spec to our string.
  1242.     But%=1
  1243.   Else
  1244.     Temp$="  Printing...  "+Chr$(0)
  1245.     Lpoke (Quit_tree%+(Canptsv%*Obj_size%)+Ob_spec%),Varptr(Temp$)   !point the dialog boxes' ob_spec to our string.
  1246.     @Check_prt(*But%)      !other wise, check if printer is ready.
  1247.     Open "",#5,"PRN:"
  1248.   Endif
  1249.   '
  1250.   If But%=1                !continue only if CANCEL button was not selected, and the printer is ready.
  1251.     @Draw_box(Quit_tree%)
  1252.     Prt_flag!=True                    !flag for output procedure: sent line to printer.
  1253.     Sp%=Max((80-Len(Filename$)-18)/2,0)                   !center the title line.
  1254.     Print #5
  1255.     Print #5
  1256.     Print #5,Space$(Sp%);"Xref listing for: ";Filename$
  1257.     Print #5,Space$(24);"Printed on: ";Date$;"  ";Time$
  1258.     Print #5
  1259.     Print #5
  1260.     Aes_ret%=0
  1261.     For T%=Start% To End%
  1262.       @Print_line(T%,0,1)
  1263.       If Mousek=1                                   !is the left mouse button pressed?
  1264.         @Check_mouse_position(Quit_tree%,Cancprt%)
  1265.       Endif
  1266.       Exit If Aes_ret%=Cancprt% Or Inkey$=Chr$(13)   !exit if CANCEL button selected or RETURN pressed.
  1267.     Next T%
  1268.     Prt_flag!=False
  1269.     @Erase_box
  1270.   Endif
  1271.   Close #5
  1272.   '
  1273. Return
  1274. '
  1275. ' -------------------------------------------------------------------------
  1276. Procedure Print_file(Start%,End%)
  1277.   Local T%,Sp%,Temp$
  1278.   '
  1279.   @Check_prt(*But%)
  1280.   If But%=1                !continue only if "RETRY" button chosen or printer is ready.
  1281.     Temp$="  Printing...  "+Chr$(0)
  1282.     Lpoke (Quit_tree%+(Canptsv%*Obj_size%)+Ob_spec%),Varptr(Temp$)   !point the dialog boxes' ob_spec to our string.
  1283.     @Draw_box(Quit_tree%)
  1284.     Sp%=Max((80-Len(Filename$)-12)/2,0)              !center the header line.
  1285.     Lprint
  1286.     Lprint
  1287.     Lprint Space$(Sp%);"Listing of: ";Filename$
  1288.     Lprint Space$(24);"Printed on: ";Date$;"  ";Time$
  1289.     Lprint
  1290.     Lprint
  1291.     Aes_ret%=0
  1292.     For T%=Start% To End%
  1293.       Lprint Using "#####_ _ &",T%+1,The_prg$(T%)
  1294.       If Mousek=1                                   !is the left mouse button pressed?
  1295.         @Check_mouse_position(Quit_tree%,Cancprt%)
  1296.       Endif
  1297.       Exit If Aes_ret%=Cancprt% Or Inkey$=Chr$(13)   !exit if CANCEL button selected or RETURN pressed.
  1298.     Next T%
  1299.     @Erase_box
  1300.   Endif
  1301. Return
  1302. '
  1303. ' -------------------------------------------------------------------------
  1304. Procedure Check_prt(A%)
  1305.   Local B%
  1306.   *A%=1
  1307.   While Gemdos(&H11)=0       !equals non-zero if printer is ready.
  1308.     Alert 3,"Printer is not ready.",1,"RETRY|CANCEL",B%
  1309.     *A%=B%
  1310.     Exit If B%=2             !if quit button was selected.
  1311.   Wend
  1312. Return
  1313. '
  1314. '
  1315. ' ********************** window, menu and blit routines *********************
  1316. '
  1317. '
  1318. Procedure Open_wind
  1319.   Local X%,Y%,W%,H%
  1320.   Local W1_attrib%,W3_attrib%,Info$
  1321.   '
  1322.   W1_attrib%=&H1D1             !title, info line, up/down arrow, vertical slider
  1323.   W3_attrib%=&HFC1             !title, up/down arrow, vert slider, left/right arrow, horz slider
  1324.   '
  1325.   @Wind_get(0,Wf_workxywh%,*X%,*Y%,*W%,*H%)
  1326.   '
  1327.   Titlew 1,"Xref listing"
  1328.   Info$=" The program has:  "+Str$(Line_number%)+" Lines  | "+Str$(Free_var%-3)+" Variables  | "+Str$(Free_proc%-3)+" Procedures  | "+Str$(Free_label%-3)+" Labels  |"
  1329.   Infow 1,Info$
  1330.   Dpoke Windtab+2,W1_attrib%
  1331.   Dpoke Windtab+4,X%
  1332.   Dpoke Windtab+6,Y%
  1333.   Dpoke Windtab+8,W%+X%
  1334.   Dpoke Windtab+10,((H%+Y%)/2)-(5*Rez%)    !only use top-half of the screen.
  1335.   '
  1336.   Openw 1
  1337.   Clearw 1
  1338.   @Wind_set(Dpeek(Windtab),Wf_vslsize%,Min(1000,1000*9/Total_lines%))   !set the vertical slider size.
  1339.   '
  1340.   Titlew 3,Filename$
  1341.   Dpoke Windtab+26,W3_attrib%
  1342.   Dpoke Windtab+28,X%
  1343.   Dpoke Windtab+30,Dpeek(Windtab+10)+(10*Rez%)   !use bottom-half of screen
  1344.   Dpoke Windtab+32,W%+X%
  1345.   Dpoke Windtab+34,(H%+Y%)-Dpeek(Windtab+30)
  1346.   '
  1347.   Openw 3
  1348.   Clearw 3
  1349.   @Wind_set(Dpeek(Windtab+24),Wf_vslsize%,Min(1000,1000*9/Line_number%))  !set the vertical slider size.
  1350.   @Wind_set(Dpeek(Windtab+24),Wf_vhlsize%,274)      !set the horz slider size.
  1351.   @Wind_set(Dpeek(Windtab+24),Wf_hslide%,0)         !init the horz slider at the left most position.
  1352.   '
  1353. Return
  1354. '
  1355. ' -------------------------------------------------------------------------
  1356. '                              AES's wind_set()
  1357. ' -------------------------------------------------------------------------
  1358. '
  1359. Procedure Wind_set(Handle%,Which%,X%)
  1360.   '
  1361.   Dpoke Gintin,Handle%
  1362.   Dpoke Gintin+2,Which%
  1363.   Dpoke Gintin+4,X%
  1364.   Gemsys 105
  1365. Return
  1366. '
  1367. ' -------------------------------------------------------------------------
  1368. '           init the arrays needed to do a raster move of the screen
  1369. ' -------------------------------------------------------------------------
  1370. '
  1371. Procedure Init_blit(Handle%,Tarray%,Barray%,Area%)
  1372.   Local X%,Y%,W%,H%
  1373.   '
  1374.   @Wind_get(Handle%,Wf_workxywh%,*X%,*Y%,*W%,*H%)   !get the size of the screen's work area.
  1375.   '
  1376.   Swap *Area%,A%()
  1377.   A%(0)=X%                     !save the window's work area for later updating (i.e. when an update mesg is received).
  1378.   A%(1)=Y%
  1379.   A%(2)=W%+X%-1
  1380.   A%(3)=Y%+H%-1
  1381.   Swap *Area%,A%()
  1382.   '
  1383.   Swap *Tarray%,Dn%()          !raster array to move the screen down one line.
  1384.   Dn%(0)=X%                    !dn%(0)-dn%(3)=the source for the raster blit.
  1385.   Dn%(1)=Y%                    !the source is the work area minus the bottom line.
  1386.   Dn%(2)=W%+X%-1
  1387.   Dn%(3)=(H%+Y%)-(8*Rez%)-1
  1388.   Dn%(4)=X%                    !dn%(4)-dn%(7)=the destination.
  1389.   Dn%(5)=Y%+(8*Rez%)           !it is the work area minus the top line.
  1390.   Dn%(6)=Dn%(2)
  1391.   Dn%(7)=H%+Y%-1
  1392.   Dn%(8)=3
  1393.   Swap *Tarray%,Dn%()
  1394.   '
  1395.   Swap *Barray%,Up%()          !raster array to move the screen up one line.
  1396.   Up%(0)=X%                    !up%(0)-up%(3)=the source.
  1397.   Up%(1)=Y%+Cell_high%         !it is the work area minus the top line.
  1398.   Up%(2)=W%+X%-1
  1399.   Up%(3)=H%+Y%-1
  1400.   Up%(4)=X%                    !up%(4)-up%(7)=the destination.
  1401.   Up%(5)=Y%                    !it is the work area minus the bottom line.
  1402.   Up%(6)=Up%(2)
  1403.   Up%(7)=Up%(3)-Cell_high%
  1404.   Up%(8)=3
  1405.   Swap *Barray%,Up%()
  1406.   '
  1407. Return
  1408. '
  1409. ' -------------------------------------------------------------------------
  1410. '                              AES's wind_get()
  1411. ' -------------------------------------------------------------------------
  1412. '
  1413. Procedure Wind_get(Handle%,Field%,Gw1%,Gw2%,Gw3%,Gw4%)
  1414.   Dpoke Gintin,Handle%
  1415.   Dpoke Gintin+2,Field%
  1416.   Gemsys 104
  1417.   '
  1418.   *Gw1%=Dpeek(Gintout+2)
  1419.   *Gw2%=Dpeek(Gintout+4)
  1420.   *Gw3%=Dpeek(Gintout+6)
  1421.   *Gw4%=Dpeek(Gintout+8)
  1422. Return
  1423. '
  1424. ' -------------------------------------------------------------------------
  1425. ' ---- disables or enables, all menu item in Search, Print, and Block. ----
  1426. ' -------------------------------------------------------------------------
  1427. ' a%=2 or 3. 2 if disabling, and 3 if enabling.
  1428. ' b%=FALSE or TRUE. FALSE if disabling control-key menu selection, and TRUE if enabling it.
  1429. ' -------------------------------------------------------------------------
  1430. '
  1431. Procedure Init_menu(A%,B%)
  1432.   Local T%,C%
  1433.   '
  1434.   Restore Which_menu_items
  1435.   '
  1436.   For T%=0 To 20
  1437.     Read C%
  1438.     Exit If C%=0
  1439.     Menu C%,A%
  1440.     Disable_item%(T%)=B%
  1441.   Next T%
  1442. Return
  1443. '
  1444. ' ******************* routines that handle dialog boxes *******************
  1445. '
  1446. Procedure Do_dial(Do_tree%,B%)
  1447.   '
  1448.   @Draw_box(Do_tree%)
  1449.   @Form_do(Do_tree%,0)
  1450.   *B%=Aes_ret%            !return which exit button was selected.
  1451.   @Erase_box
  1452. Return
  1453. '
  1454. ' -------------------------------------------------------------------------
  1455. Procedure Draw_box(Draw_tree%)
  1456.   '
  1457.   @Form_center(Draw_tree%,*Box_x%,*Box_y%,*Box_w%,*Box_h%)
  1458.   @Form_dial(Fmd_start%,Box_x%,Box_y%,Box_w%,Box_h%)
  1459.   @Form_dial(Fmd_grow%,Box_x%,Box_y%,Box_w%,Box_h%)
  1460.   @Objc_draw(Draw_tree%,0,20,Box_x%,Box_y%,Box_w%,Box_h%)
  1461.   '
  1462. Return
  1463. '
  1464. ' -------------------------------------------------------------------------
  1465. Procedure Erase_box
  1466.   '
  1467.   @Form_dial(Fmd_shrink%,Box_x%,Box_y%,Box_w%,Box_h%)
  1468.   @Form_dial(Fmd_finish%,Box_x%,Box_y%,Box_w%,Box_h%)
  1469. Return
  1470. '
  1471. ' -------------------------------------------------------------------------
  1472. Procedure Check_mouse_position(Tree%,Button%)
  1473.   Local X%,Y%,B%
  1474.   '
  1475.   Aes_ret%=0                             !clear flag.
  1476.   @Graf_mkstate(*X%,*Y%,*B%,*Dum%)       !get mouse's position.
  1477.   @Objc_find(Tree%,Button%,10,X%,Y%)     !is the mouse over the button?
  1478.   '
  1479. Return
  1480. '
  1481. ' -------------------------------------------------------------------------
  1482. '                           AES's graf_mkstate
  1483. ' -------------------------------------------------------------------------
  1484. '
  1485. Procedure Graf_mkstate(Gr_mkmx%,Gr_mkmy%,Gr_mkmstate%,Gr_mkkstate%)
  1486.   '
  1487.   Gemsys 79
  1488.   *Gr_mkmx%=Dpeek(Gintout+2)             !returns the mouse's x and y pos, button state, and certain key states.
  1489.   *Gr_mkmy%=Dpeek(Gintout+4)
  1490.   *Gr_mkmstate%=Dpeek(Gintout+6)
  1491.   *Gr_mkkstate%=Dpeek(Gintout+8)
  1492. Return
  1493. '
  1494. '
  1495. ' -------------------------------------------------------------------------
  1496. ' ------------------------  object library routines  ----------------------
  1497. ' -------------------------------------------------------------------------
  1498. '
  1499. '
  1500. Procedure Objc_draw(Ob_tree%,Ob_start%,Ob_depth%,X%,Y%,W%,H%)
  1501.   Dpoke Gintin,Ob_start%
  1502.   Dpoke Gintin+2,Ob_depth%
  1503.   Dpoke Gintin+4,X%
  1504.   Dpoke Gintin+6,Y%
  1505.   Dpoke Gintin+8,W%
  1506.   Dpoke Gintin+10,H%
  1507.   Lpoke Addrin,Ob_tree%
  1508.   Gemsys 42
  1509.   '
  1510.   Aes_ret%=Dpeek(Gintout)
  1511. Return
  1512. '
  1513. ' -------------------------------------------------------------------------
  1514. Procedure Objc_find(Ob_tree%,Ob_start%,Ob_depth%,Xms%,Yms%)
  1515.   Dpoke Gintin,Ob_start%
  1516.   Dpoke Gintin+2,Ob_depth%
  1517.   Dpoke Gintin+4,Xms%
  1518.   Dpoke Gintin+6,Yms%
  1519.   Lpoke Addrin,Ob_tree%
  1520.   Gemsys 43
  1521.   '
  1522.   Aes_ret%=Dpeek(Gintout)
  1523. Return
  1524. '
  1525. ' -------------------------------------------------------------------------
  1526. Procedure Objc_offset(Ob_tree%,Ob_ofobject%,Ob_xoff%,Ob_yoff%)
  1527.   Dpoke Gintin,Ob_ofobject%
  1528.   Lpoke Addrin,Ob_tree%
  1529.   Gemsys 44
  1530.   '
  1531.   *Ob_xoff%=Dpeek(Gintout+2)
  1532.   *Ob_yoff%=Dpeek(Gintout+4)
  1533. Return
  1534. '
  1535. '
  1536. ' -------------------------------------------------------------------------
  1537. ' -------------------------  form library routines  -----------------------
  1538. ' -------------------------------------------------------------------------
  1539. '
  1540. Procedure Form_do(Ob_tree%,Fo_start%)
  1541.   Dpoke Gintin,Fo_start%
  1542.   Lpoke Addrin,Ob_tree%
  1543.   Gemsys 50
  1544.   '
  1545.   Aes_ret%=Dpeek(Gintout)
  1546. Return
  1547. '
  1548. ' -------------------------------------------------------------------------
  1549. Procedure Form_dial(Fo_flag%,Xbig%,Ybig%,Wbig%,Hbig%)
  1550.   Dpoke Gintin,Fo_flag%
  1551.   Dpoke Gintin+2,Xbig%+(Wbig%/2)
  1552.   Dpoke Gintin+4,Ybig%+(Hbig%/2)
  1553.   Dpoke Gintin+6,1
  1554.   Dpoke Gintin+8,1
  1555.   Dpoke Gintin+10,Xbig%
  1556.   Dpoke Gintin+12,Ybig%
  1557.   Dpoke Gintin+14,Wbig%
  1558.   Dpoke Gintin+16,Hbig%
  1559.   Gemsys 51
  1560.   '
  1561.   Aes_ret%=Dpeek(Gintout)
  1562. Return
  1563. '
  1564. ' -------------------------------------------------------------------------
  1565. Procedure Form_center(Cent_tree%,Cent_x%,Cent_y%,Cent_w%,Cent_h%)
  1566.   Lpoke Addrin,Cent_tree%
  1567.   Gemsys 54
  1568.   '
  1569.   Aes_ret%=Dpeek(Gintout)
  1570.   *Cent_x%=Dpeek(Gintout+2)
  1571.   *Cent_y%=Dpeek(Gintout+4)
  1572.   *Cent_w%=Dpeek(Gintout+6)
  1573.   *Cent_h%=Dpeek(Gintout+8)
  1574. Return
  1575. '
  1576. '
  1577. ' -------------------------------------------------------------------------
  1578. ' -----------------------  resource library routines  ---------------------
  1579. ' -------------------------------------------------------------------------
  1580. '
  1581. Procedure Rsrc_load(Re_fname$)
  1582.   Lpoke Addrin,Varptr(Re_fname$)
  1583.   Gemsys 110
  1584.   '
  1585.   Aes_ret%=Dpeek(Gintout)
  1586. Return
  1587. '
  1588. ' -------------------------------------------------------------------------
  1589. Procedure Rsrc_free
  1590.   Gemsys 111
  1591.   '
  1592. Return
  1593. '
  1594. ' -------------------------------------------------------------------------
  1595. Procedure Rsrc_gaddr(Re_type%,Re_index%,Re_tree%)
  1596.   Dpoke Gintin,Re_type%
  1597.   Dpoke Gintin+2,Re_index%
  1598.   Gemsys 112
  1599.   '
  1600.   Aes_ret%=Dpeek(Gintout)
  1601.   *Re_tree%=Lpeek(Addrout)
  1602. Return
  1603. '
  1604. '
  1605. ' ****************************  VDI routines  ***************************
  1606. '
  1607. '
  1608. ' -------------------------------------------------------------------------
  1609. ' draws the 'percentage of file complete' bar in the 'Cross ref...' dialog box.
  1610. ' -------------------------------------------------------------------------
  1611. '
  1612. Procedure V_bar(X%,Y%,W%,H%)
  1613.   '
  1614.   Dpoke Contrl,11
  1615.   Dpoke Contrl+2,2
  1616.   Dpoke Contrl+6,0
  1617.   Dpoke Contrl+10,1
  1618.   Dpoke Ptsin,X%
  1619.   Dpoke Ptsin+2,Y%
  1620.   Dpoke Ptsin+4,W%
  1621.   Dpoke Ptsin+6,H%
  1622.   Vdisys
  1623.   '
  1624. Return
  1625. '
  1626. ' -------------------------------------------------------------------------
  1627. '    draws a filled borderless box. used to highlight a block of text.
  1628. ' -------------------------------------------------------------------------
  1629. '
  1630. Procedure Vr_recfl(X%,Y%,W%,H%)
  1631.   '
  1632.   Dpoke Contrl,114
  1633.   Dpoke Contrl+2,2
  1634.   Dpoke Contrl+6,0
  1635.   Dpoke Ptsin,X%
  1636.   Dpoke Ptsin+2,Y%
  1637.   Dpoke Ptsin+4,W%
  1638.   Dpoke Ptsin+6,H%
  1639.   Vdisys
  1640.   '
  1641. Return
  1642. '
  1643. ' -------------------------------------------------------------------------
  1644. Procedure Clip(A%)
  1645.   '
  1646.   Dpoke Contrl,129
  1647.   Dpoke Contrl+2,2
  1648.   Dpoke Contrl+6,1
  1649.   Dpoke Gintin,A%         !if a%=0, then clipping is disabled, otherwise, it's enabled.
  1650.   Vdisys
  1651.   '
  1652. Return
  1653. '
  1654. '
  1655. ' **************************  data for menu  ***************************
  1656. '
  1657. Data Desk,  About Xref...
  1658. Data ----------------------
  1659. Data 1,2,3,4,5,6,""
  1660. Data File,  Open file...           ^O ,  Save all of Xref...    ^V ,  Save block of Xref...  ^F ,----------------------------,  Quit                   ^Q ,""
  1661. Data Search,  Search...       ^S ,---------------------,  Goto line #...  ^G ,""
  1662. Data Print,  All of Xref     ^P ,  Block of Xref   ^B ,---------------------,  All of File     ^A ,  Block of File   ^K ,""
  1663. Data Block,  Unmark Block  ^U ,""
  1664. Data END
  1665. '
  1666. Which_menu_items:
  1667. '
  1668. Data 12,13,18,20,23,24,26,27,30,0
  1669. '
  1670. ' machine language routine used in the get_whatever procedure.
  1671. '
  1672. '
  1673. Data &H22,&H6F,&H0,&H6,&H20,&H19,&H26,&H19,&H20,&H59,&H22,&H51,&H42,&H29,&H0
  1674. Data &H9A,&H42,&H29,&H0,&H9B,&H42,&H29,&H0,&H9C,&HB6,&H40,&H63,&H20,&H12,&H30
  1675. Data &H0,&HFF,&HB2,&H3C,&H0,&H22,&H67,&H66,&HB2,&H3C,&H0,&H21,&H67,&H10,&HB2
  1676. Data &H3C,&H0,&H61,&H6D,&H6,&HB2,&H3C,&H0,&H7A,&H6F,&HC,&H52,&H40,&H60,&HDC
  1677. Data &H13,&H7C,&HFF,&HFF,&H0,&H9A,&H4E,&H75,&H13,&H40,&H0,&H9A,&H52,&H40,&H12
  1678. Data &H30,&H0,&HFF,&HB2,&H3C,&H0,&H21,&H67,&HF4,&HB2,&H3C,&H0,&H24,&H67,&HEE
  1679. Data &HB2,&H3C,&H0,&H25,&H67,&HE8,&HB2,&H3C,&H0,&H5F,&H67,&HE2,&HB2,&H3C,&H0
  1680. Data &H30,&H6D,&H16,&HB2,&H3C,&H0,&H39,&H6F,&HD6,&HB2,&H3C,&H0,&H61,&H6D,&HA
  1681. Data &HB2,&H3C,&H0,&H7A,&H6E,&H4,&HB6,&H40,&H62,&HC6,&H13,&H40,&H0,&H9B,&H13
  1682. Data &H41,&H0,&H9C,&H4E,&H75,&H52,&H40,&H12,&H30,&H0,&HFF,&HB2,&H3C,&H0,&H22
  1683. Data &H66,&HF4,&H60,&H9E,&H0,&H0,&H0
  1684.